Recordings split into fragments and stops

Use MediaPortal TV Server to tune and record analog or digital TV
mate
Posts: 24
Joined: Wed Dec 05, 2012 10:28 pm

Re: Recordings split into fragments and stops

Post by mate » Mon Dec 10, 2012 11:39 pm

andrewNZ wrote:I've not had good experiences recording to a drive extender share. I added an additional external HDD for Argus TV (and it's ancestor) to use.

I always found drive extender caused glitches and stutter. But I mostly put it down to hardware, the H340 isn't exactly high powered.
I have recorded to Drive Extender share for two years, hundreds - if not thousands - of recordings, and only had problems with a handful.

I can however confirm, that recording to non-DE shares seems to work fine with Argus 2.0.1 (Argus recorder).

After updating FTR from 1.6 to 1.7, it looks like the first two recording went well, and then all others have the problem described in this thread. Problems continue with Argus TV 2.0.1. It seems to me, that something in this regard was changed in For The Record 1.7 (such as what I mention above). From a WHSv1 Driver Extender perspective, the change was to the worse.

What are the chances someone will look into what happened in FTR 1.7, and in a future Argus release we are able to record to DE shares again...?


In the meantime, I assume I should create a Processing Command that moves the files from a temporary non-DE share, to a DE share (\Recorded TV). Has anyone created such command they'd like to share...? The trick here would be how to get a folder with the recording title in the destination folder (like it is in the recording folder). The Processing Commands screen says %%CHANNEL%% is available in the arguments box, but hopefully %%TITLE%% is too. I'll run a few tests unless someone already knows / has a solution.
Hauppauge WinTV 88x DVB-T
Windows Home Server
EPG grabbed from DVB-T

Christoph21x
Posts: 1070
Joined: Wed Oct 19, 2011 9:39 am
Location: Berne / Switzerland
Contact:

Re: Recordings split into fragments and stops

Post by Christoph21x » Tue Dec 11, 2012 12:02 am

Hi mate!

I personally use robocopy to move files from the recording directory and its subs.
It it slower but has some nice features: lowering throughput if network is used, resume after breakdown (fail-safe) etc. If you want to have the params, let me know.

There's a good post of Sjakko under viewtopic.php?p=24982#p24982 treating this as well.

Greetz - Chris
"One must still have chaos within oneself, to give birth to a dancing star." (F. Nietzsche)

mate
Posts: 24
Joined: Wed Dec 05, 2012 10:28 pm

Re: Recordings split into fragments and stops

Post by mate » Tue Dec 11, 2012 12:07 am

I'll definitely look into Robocopy. Having an example to look at would be great.
For some reason I am not authorized to view the linked thread.
Hauppauge WinTV 88x DVB-T
Windows Home Server
EPG grabbed from DVB-T

Christoph21x
Posts: 1070
Joined: Wed Oct 19, 2011 9:39 am
Location: Berne / Switzerland
Contact:

Re: Recordings split into fragments and stops

Post by Christoph21x » Tue Dec 11, 2012 12:23 am

Good choice, as it is part of your Win distribution (and needs no additional installation) - and I'm NOT a blind Win-Believer ;)
There's quite a good iteration on the parameters under http://www.mydigitallife.info/robocopy- ... -examples/

I don't use it as a post-processing command but as a batch cmd that is started from task manager - but you can adopt that easily.
My recording Directory is C:\Recorded TV and I select the subfolders (recorded series / recorded films) from within the "Recording File Fomats"

sample cmd line:
robocopy "C:\Recorded TV\Recorded Series" "\\192.168.0.199\Recorded_TV\Recorded Series" /MOV /V /R:10 /W:30 /IS /S /PF /RH:0530-1950 /XD /Z dirs TempRec

Comments:
- am using IP addresses because this will connect on runtime and not try to contact named shares (may be a problem after wake-up of the server)
- /MOV - move instead of copy
- /Z sets "resumable" but slows down (need not with a fast and almost-always up network)
- /RH only run between (local time): using this only during the day (when nearly no recording takes place)
- /XD dirs TempRec - excludes the subdirectory "TempRec"
- etc... see link above

if you want to make it really fail-safe, change any read-only attribute prior to that cmd to read/write:
attrib -R "C:\Recorded TV\Recorded Series\*.*"

Greetz - Chris
"One must still have chaos within oneself, to give birth to a dancing star." (F. Nietzsche)

mate
Posts: 24
Joined: Wed Dec 05, 2012 10:28 pm

Re: Recordings split into fragments and stops

Post by mate » Tue Dec 11, 2012 8:01 am

That's all great, but I don't quite see how it solves my problem.

Say I record to C:\Recorded TV.
Then as soon as C:\Recorded TV\Friends\Friends_2012-12-11_22-00.ts is finished recording, I want to run a Processing Commands that moves it to \\server\Recorded TV\Friends\Friends_2012-12-11_22-00.ts without interfering with C:\Recorded TV\Sex And The City\Sex And The City_2012-12-11_22-30.ts currently being recorded (and which, when done, should end up in \\server\Recorded TV\Sex And The City\Sex And The City_2012-12-11_22-30.ts).

That is, I want to copy a single file, including 1 level of parent directories.
I do not want batch processing due to a) the delay and b) I don't want to interfere with running recordings.

I have tested the Processing Command parameters, and out of %%FILE%% %%FILE2%% %%LONGTITLE%% %%CHANNEL%% %%DATE%% %%HOURS%% %%MINUTES%% %%TITLE%% is seems only %%FILE%% %%FILE2%% and %%CHANNEL%% works. Otherwise I could simply have told Robocopy to copy %%FILE%% to \\server\Recorded TV\%%TITLE%%. So that is a feature request.
Hauppauge WinTV 88x DVB-T
Windows Home Server
EPG grabbed from DVB-T

Christoph21x
Posts: 1070
Joined: Wed Oct 19, 2011 9:39 am
Location: Berne / Switzerland
Contact:

Re: Recordings split into fragments and stops

Post by Christoph21x » Tue Dec 11, 2012 8:07 am

Depedning on your recordings name format...
can't you use it like this:
robocopy ..\%FILE%*.* /S
where ".." selects the parent dir where robocopy is started from including sub dirs.

Or you use the date/time parameters with robocopy to select the most recent recordings.
It will then also copy the active recording, but doesn't matter; it's not interfering (here the same, also current recordings are copied, but it has no impact). The next time, the recording ends, it will then move this file as its date/time is newer to the already copied part of the recording.
"One must still have chaos within oneself, to give birth to a dancing star." (F. Nietzsche)

Christoph21x
Posts: 1070
Joined: Wed Oct 19, 2011 9:39 am
Location: Berne / Switzerland
Contact:

Re: Recordings split into fragments and stops

Post by Christoph21x » Tue Dec 11, 2012 11:04 am

... and as you were not able to open the thread mentioned above - here's a copy:
(author: Sjakko)
==================================
Please take into account that you may encounter overwritten files in some situations. Say a recording is aborted, and then resumed again. Normally on resume a new file is created with a unique name ("_1"/"_2"/... addition). But if the file is moved after aborting, no unique file will be created and when moving this one it may overwrite the first part. Knowing that, you can use the following cmd:

Just move the ts file assuming the destination directory exists:

Code: Select all

MOVE /Y "%~1" "Z:\TV\%~nx1"
But for safety you may also want to create the destination directory (Z:\TV) and move the 4tr and thmb file:

Code: Select all

set dir=Z:\TV
MD "%dir%"
MOVE /Y "%~1" "%dir%\%~nx1"
MOVE /Y "%~dpn1.4tr" "%dir%\%~n1.4tr"
MOVE /Y "%~dpn1.thmb" "%dir%\%~n1.thmb"
Place it inside a .cmd file and run it as a Processing Command with %%FILE%% as only parameter. You may want to give it a minute delay there because thmb creation may take a second or 2.

If you want to move the whole directory you may consider using Robocopy but you'll see the same problem described above. You need some way of creating unique file names. I can imagine this is quite tricky in batch/cmd.
"One must still have chaos within oneself, to give birth to a dancing star." (F. Nietzsche)

mate
Posts: 24
Joined: Wed Dec 05, 2012 10:28 pm

Re: Recordings split into fragments and stops

Post by mate » Tue Dec 11, 2012 9:45 pm

This seems to do what I want, in case it helps anyone else

Code: Select all

@echo off

setlocal

REM TODO: Change DEST_PARENT according to your preference
SET DEST_PARENT=\\whs\Recorded TV
SET FILENAME=%~nx1
SET SOURCE_DIR=%~dp1

REM See http://stackoverflow.com/questions/2396003/get-parent-directory-name-for-a-particular-file-using-dos-batch-scripting
set ParentDir=%~p1
set ParentDir=%ParentDir: =:%
set ParentDir=%ParentDir:\= %
call :getparentdir %ParentDir%
set ParentDir=%ParentDir::= %

SET DEST_DIR="%DEST_PARENT%\%ParentDir%"

REM Some loggin?
REM echo Moving recording: "%FILENAME%" from "%SOURCE_DIR%" to %DEST_DIR% >> d:\argus\move.log

REM Make sure destination directory exists
IF NOT EXIST %DEST_DIR% MKDIR %DEST_DIR%
REM Move the file
move %1 %DEST_DIR%
REM Removing any .thmb files
DEL "%SOURCE_DIR%\*.thmb"
REM Deleting directory, if empty
rmdir "%SOURCE_DIR%"

goto :EOF

REM --------------------

:getparentdir
if "%~1" EQU "" goto :EOF
Set ParentDir=%~1
shift
goto :getparentdir
Hauppauge WinTV 88x DVB-T
Windows Home Server
EPG grabbed from DVB-T

clintwelbar
Posts: 1
Joined: Thu Dec 17, 2015 9:43 am
Contact:

Re: Recordings split into fragments and stops

Post by clintwelbar » Thu Dec 17, 2015 9:45 am

Check this one, more about.....Robocopy

Clint

Post Reply

Who is online

Users browsing this forum: No registered users and 1 guest